Arduino Basics: CH376S USB Read/Write module

7 May 2015

CH376S USB Read/Write module

Have you ever wondered if there was a way to store and retrieve data from a USB stick with an Arduino UNO? Most people choose SD cards to store their project data, but you may be surprised there IS a way!
IC Station have a nice little module which allows you store and retrieve your Arduino (or other MCU) project data to a USB stick.

I am not too sure why USB storage is not widely used in Arduino projects? These modules are not expensive, they have been around for quite a while, and are relatively simple to use. You do not need any libraries to get them to work, however, I must say that documentation for this module is not that easy to find. This site and this document proved to be very useful in my endevour to get this module working, and I hope my tutorial below will help you get started and bridge some of the information gaps.

The "CH376S USB read/write module" has a CH376S chip onboard which does most of the hard work for you. All you have to do is send the module some commands from the Arduino and the CH376S chip will do the rest. You can communicate with the module in three different ways:

Parallel communication
SPI communication
and Serial (UART) communication.

This project will show you the connections and code for the Serial (UART) communication method only.

Parts Required:

Remove the Jumper

When the CH376S USB module arrives in it's package, it will have a jumper between the TXD pin and GND. You will need to remove this jumper to make the necessary connections between the Arduino UNO and the CH376S USB module.

Fritzing Sketch

Please note, that the Arduino Sketch makes use of the Arduino UNO's onboard LED on digital pin 13. The Fritzing sketch below shows an LED + 300 ohm resistor on a breadboard. This is optional. The LED is not a necessary component of CH376S module communication.

Also be aware that the CH376S USB module has an onboard LED just above the TXD and GND pins near the USB port. This LED will only turn on providing the CH376S module is in USB mode AND a USB device has been inserted into the USB port. Both conditions must be met before the module's onboard LED will illuminate. You will not see the LED turn on just by powering the board.

The wire diagram below is the correct setup for Serial communication between an Arduino UNO and the CH376S module. If you wish to use SPI or Parallel communication, you will need to refer to the datasheet.

Arduino Sketch

/* ===============================================================
      Project: CH376S USB Read/Write Module testing ground
       Author: Scott C
      Created: 1st May 2015
  Arduino IDE: 1.6.2
      Website: http://arduinobasics.blogspot.com/p/arduino-basics-projects-page.html
  Description: This project will allow you to perform many of the functions available on the CH376S module.
               Checking connection to the module, putting the module into USB mode, resetting the module, 
               reading, writing, appending text to files on the USB stick. This is very useful alternative to
               SD card modules, plus it doesn't need any libraries.
================================================================== */

#include <SoftwareSerial.h>

byte computerByte;           //used to store data coming from the computer
byte USB_Byte;               //used to store data coming from the USB stick
int LED = 13;                //the LED is connected to digital pin 13 
int timeOut = 2000;          //TimeOut is 2 seconds. This is the amount of time you wish to wait for a response from the CH376S module.
String wrData = "What is the meaning of life ?";     //We will write this data to a newly created file.
String wrData2 = "42";                                   //We will append this data to an already existing file.

SoftwareSerial USB(10, 11);                           // Digital pin 10 on Arduino (RX) connects to TXD on the CH376S module
                                                      // Digital pin 11 on Arduino (TX) connects to RXD on the CH376S module
                                                      // GND on Arduino to GND on CH376S module
                                                      // 5V on Arduino to 5V on CH376S module
//==============================================================================================================================================
void setup() {
  Serial.begin(9600);                                 // Setup serial communication with the computer (using a baud rate of 9600 on serial monitor)
  USB.begin(9600);                                    // Setup serial communication with the CH376S module (using the default baud rate of 9600)
  pinMode(LED,OUTPUT);                                // Define digital pin 13 as an OUTPUT pin - so that we can use it with an LED
  digitalWrite(LED,LOW);                              // Turn off the LED
}

//================================================================================================================================================
void loop() {
  if(Serial.available()){
    computerByte = Serial.read();                      //read any incoming bytes from the Serial monitor, and store this byte in the variable called computerByte
    if(computerByte==49){               //1            //If you send the number 1 from the serial monitor, the arduino will read it as digital number 49. Google "ascii table" for more info.
      printCommandHeader("COMMAND1: CHECK CONNECTION");
      checkConnection(0x01);                           // Check for successful connection and communication with the CH376S module.
    } 
    if(computerByte==50){               //2
     printCommandHeader("COMMAND2: set_USB_Mode");
      set_USB_Mode(0x06);                              // Code used to enable read/write communication and monitoring of the USB stick
    }
    if(computerByte==51){               //3
      printCommandHeader("COMMAND3: resetALL");
      resetALL();                                      // Reset the USB device
    }
    if(computerByte==52){               //4
      printCommandHeader("COMMAND4: Create and Write to File : TEST4.TXT");
      writeFile("TEST4.TXT", wrData);                  // Create a file called TEST4.TXT and then Write the contents of wrData to this file
    }
    if(computerByte==53){               //5
      printCommandHeader("COMMAND5: Read File: TEST4.TXT");
      readFile("TEST4.TXT");                           // Read the contents of this file on the USB disk, and display contents in the Serial Monitor
    }
    if(computerByte==54){               //6
      printCommandHeader("COMMAND6: Append data to file: TEST4.TXT");
      appendFile("TEST4.TXT", wrData2);                // Append data to the end of the file.
    }
    if(computerByte==55){               //7
      printCommandHeader("COMMAND7: Delete File: TEST4.TXT");
      fileDelete("TEST4.TXT");                         // Delete the file named TEST4.TXT
    }
    if(computerByte==56){               //8
      printCommandHeader("COMMAND8: Read File: TEST2.TXT");
      readFile("TEST2.TXT");                           // Read the contents of the TEST2.TXT file on the USB disk, and display contents in the Serial Monitor
    }
    if(computerByte==57){               //9
      printCommandHeader("COMMAND9: Read File: TEST3.TXT");
      readFile("TEST3.TXT");                           // Read the contents of the TEST3.TXT file on the USB disk, and display contents in the Serial Monitor
    }
  }
  
  if(USB.available()){                                 // This is here to capture any unexpected data transmitted by the CH376S module
    Serial.print("CH376S has just sent this code:");
    Serial.println(USB.read(), HEX);
  }
}

//END OF LOOP FUNCTION ========================================================================================================================================

//print Command header
void printCommandHeader(String header){
   Serial.println("======================");
   Serial.println("");
   Serial.println(header);
   Serial.println("----------------------");
}

//checkConnection==================================================================================
//This function is used to check for successful communication with the CH376S module. This is not dependant of the presence of a USB stick.
//Send any value between 0 to 255, and the CH376S module will return a number = 255 - value. 
void checkConnection(byte value){
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x06);
  USB.write(value);
  
  if(waitForResponse("checking connection")){       //wait for a response from the CH376S. If CH376S responds, it will be true. If it times out, it will be false.
    if(getResponseFromUSB()==(255-value)){
       Serial.println(">Connection to CH376S was successful.");
       blinkLED();                               //blink the LED for 1 second if the connection was successful
    } else {
      Serial.print(">Connection to CH376S - FAILED.");
    }
  }
}

//set_USB_Mode=====================================================================================
//Make sure that the USB is inserted when using 0x06 as the value in this specific code sequence
void set_USB_Mode (byte value){
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x15);
  USB.write(value);
  
  delay(20);
  
  if(USB.available()){
    USB_Byte=USB.read();
    //Check to see if the command has been successfully transmitted and acknowledged.
    if(USB_Byte==0x51){                                   // If true - the CH376S has acknowledged the command.
        Serial.println("set_USB_Mode command acknowledged"); //The CH376S will now check and monitor the USB port
        USB_Byte = USB.read();
        
        //Check to see if the USB stick is connected or not.
        if(USB_Byte==0x15){                               // If true - there is a USB stick connected
          Serial.println("USB is present");
          blinkLED();                                     // If the process was successful, then turn the LED on for 1 second 
        } else {
          Serial.print("USB Not present. Error code:");   // If the USB is not connected - it should return an Error code = FFH
          Serial.print(USB_Byte, HEX);
          Serial.println("H");
        }
        
    } else {
        Serial.print("CH3765 error!   Error code:");
        Serial.print(USB_Byte, HEX);
        Serial.println("H");
    }   
  }
  delay(20);
}

//resetALL=========================================================================================
//This will perform a hardware reset of the CH376S module - which usually takes about 35 msecs =====
void resetALL(){
    USB.write(0x57);
    USB.write(0xAB);
    USB.write(0x05);
    Serial.println("The CH376S module has been reset !");
    delay(200);
}

//readFile=====================================================================================
//This will send a series of commands to read data from a specific file (defined by fileName)
void readFile(String fileName){
  resetALL();                     //Reset the module
  set_USB_Mode(0x06);             //Set to USB Mode
  diskConnectionStatus();         //Check that communication with the USB device is possible
  USBdiskMount();                 //Prepare the USB for reading/writing - you need to mount the USB disk for proper read/write operations.
  setFileName(fileName);          //Set File name
  fileOpen();                     //Open the file for reading
  int fs = getFileSize();         //Get the size of the file
  fileRead();                     //***** Send the command to read the file ***
  fileClose(0x00);                //Close the file
}

//writeFile========================================================================================
//is used to create a new file and then write data to that file. "fileName" is a variable used to hold the name of the file (e.g TEST.TXT). "data" should not be greater than 255 bytes long. 
void writeFile(String fileName, String data){
  resetALL();                     //Reset the module
  set_USB_Mode(0x06);             //Set to USB Mode
  diskConnectionStatus();         //Check that communication with the USB device is possible
  USBdiskMount();                 //Prepare the USB for reading/writing - you need to mount the USB disk for proper read/write operations.
  setFileName(fileName);          //Set File name
  if(fileCreate()){               //Try to create a new file. If file creation is successful
    fileWrite(data);              //write data to the file.
  } else {
    Serial.println("File could not be created, or it already exists");
  }
  fileClose(0x01);
}

//appendFile()====================================================================================
//is used to write data to the end of the file, without erasing the contents of the file.
void appendFile(String fileName, String data){
    resetALL();                     //Reset the module
    set_USB_Mode(0x06);             //Set to USB Mode
    diskConnectionStatus();         //Check that communication with the USB device is possible
    USBdiskMount();                 //Prepare the USB for reading/writing - you need to mount the USB disk for proper read/write operations.
    setFileName(fileName);          //Set File name
    fileOpen();                     //Open the file
    filePointer(false);             //filePointer(false) is to set the pointer at the end of the file.  filePointer(true) will set the pointer to the beginning.
    fileWrite(data);                //Write data to the end of the file
    fileClose(0x01);                //Close the file using 0x01 - which means to update the size of the file on close. 
}
  
//setFileName======================================================================================
//This sets the name of the file to work with
void setFileName(String fileName){
  Serial.print("Setting filename to:");
  Serial.println(fileName);
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x2F);
  USB.write(0x2F);         // Every filename must have this byte to indicate the start of the file name.
  USB.print(fileName);     // "fileName" is a variable that holds the name of the file.  eg. TEST.TXT
  USB.write((byte)0x00);   // you need to cast as a byte - otherwise it will not compile.  The null byte indicates the end of the file name.
  delay(20);
}

//diskConnectionStatus================================================================================
//Check the disk connection status
void diskConnectionStatus(){
  Serial.println("Checking USB disk connection status");
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x30);

  if(waitForResponse("Connecting to USB disk")){       //wait for a response from the CH376S. If CH376S responds, it will be true. If it times out, it will be false.
    if(getResponseFromUSB()==0x14){               //CH376S will send 0x14 if this command was successful
       Serial.println(">Connection to USB OK");
    } else {
      Serial.print(">Connection to USB - FAILED.");
    }
  }
}

//USBdiskMount========================================================================================
//initialise the USB disk and check that it is ready - this process is required if you want to find the manufacturing information of the USB disk
void USBdiskMount(){
  Serial.println("Mounting USB disk");
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x31);

  if(waitForResponse("mounting USB disk")){       //wait for a response from the CH376S. If CH376S responds, it will be true. If it times out, it will be false.
    if(getResponseFromUSB()==0x14){               //CH376S will send 0x14 if this command was successful
       Serial.println(">USB Mounted - OK");
    } else {
      Serial.print(">Failed to Mount USB disk.");
    }
  }
}

//fileOpen========================================================================================
//opens the file for reading or writing
void fileOpen(){
  Serial.println("Opening file.");
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x32);
  if(waitForResponse("file Open")){                 //wait for a response from the CH376S. If CH376S responds, it will be true. If it times out, it will be false.
    if(getResponseFromUSB()==0x14){                 //CH376S will send 0x14 if this command was successful  
       Serial.println(">File opened successfully.");
    } else {
      Serial.print(">Failed to open file.");
    }
  }
}

//setByteRead=====================================================================================
//This function is required if you want to read data from the file. 
boolean setByteRead(byte numBytes){
  boolean bytesToRead=false;
  int timeCounter = 0;
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x3A);
  USB.write((byte)numBytes);   //tells the CH376S how many bytes to read at a time
  USB.write((byte)0x00);
  if(waitForResponse("setByteRead")){       //wait for a response from the CH376S. If CH376S responds, it will be true. If it times out, it will be false.
    if(getResponseFromUSB()==0x1D){         //read the CH376S message. If equal to 0x1D, data is present, so return true. Will return 0x14 if no data is present.
      bytesToRead=true;
    }
  }
  return(bytesToRead);
} 

//getFileSize()===================================================================================
//writes the file size to the serial Monitor.
int getFileSize(){
  int fileSize=0;
  Serial.println("Getting File Size");
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x0C);
  USB.write(0x68);
  delay(100);
  Serial.print("FileSize =");
  if(USB.available()){
    fileSize = fileSize + USB.read();
  } 
  if(USB.available()){
    fileSize = fileSize + (USB.read()*255);
  } 
  if(USB.available()){
    fileSize = fileSize + (USB.read()*255*255);
  } 
  if(USB.available()){
    fileSize = fileSize + (USB.read()*255*255*255);
  }     
  Serial.println(fileSize);
  delay(10);
  return(fileSize);
}


//fileRead========================================================================================
//read the contents of the file
void fileRead(){
  Serial.println("Reading file:");
  byte firstByte = 0x00;                     //Variable to hold the firstByte from every transmission.  Can be used as a checkSum if required.
  byte numBytes = 0x40;                      //The maximum value is 0x40  =  64 bytes
 
  while(setByteRead(numBytes)){              //This tells the CH376S module how many bytes to read on the next reading step. In this example, we will read 0x10 bytes at a time. Returns true if there are bytes to read, false if there are no more bytes to read.
    USB.write(0x57);
    USB.write(0xAB);
    USB.write(0x27);                          //Command to read ALL of the bytes (allocated by setByteRead(x))
    if(waitForResponse("reading data")){      //Wait for the CH376S module to return data. TimeOut will return false. If data is being transmitted, it will return true.
        firstByte=USB.read();                 //Read the first byte
        while(USB.available()){
          Serial.write(USB.read());           //Send the data from the USB disk to the Serial monitor
          delay(1);                           //This delay is necessary for successful Serial transmission
        }
    }
    if(!continueRead()){                       //prepares the module for further reading. If false, stop reading.
      break;                                   //You need the continueRead() method if the data to be read from the USB device is greater than numBytes.
    }
  }
  Serial.println();
  Serial.println("NO MORE DATA");
}

//fileWrite=======================================================================================
//are the commands used to write to the file
void fileWrite(String data){
  Serial.println("Writing to file:");
  byte dataLength = (byte) data.length();         // This variable holds the length of the data to be written (in bytes)
  Serial.println(data);
  Serial.print("Data Length:");
  Serial.println(dataLength);
  delay(100);
  // This set of commands tells the CH376S module how many bytes to expect from the Arduino.  (defined by the "dataLength" variable)
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x3C);
  USB.write((byte) dataLength);
  USB.write((byte) 0x00);
  if(waitForResponse("setting data Length")){      // Wait for an acknowledgement from the CH376S module before trying to send data to it
    if(getResponseFromUSB()==0x1E){                // 0x1E indicates that the USB device is in write mode.
      USB.write(0x57);
      USB.write(0xAB);
      USB.write(0x2D);
      USB.print(data);                             // write the data to the file
  
      if(waitForResponse("writing data to file")){   // wait for an acknowledgement from the CH376S module
      }
      Serial.print("Write code (normally FF and 14): ");
      Serial.print(USB.read(),HEX);                // code is normally 0xFF
      Serial.print(",");
      USB.write(0x57);
      USB.write(0xAB);
      USB.write(0x3D);                             // This is used to update the file size. Not sure if this is necessary for successful writing.
      if(waitForResponse("updating file size")){   // wait for an acknowledgement from the CH376S module
      }
      Serial.println(USB.read(),HEX);              //code is normally 0x14
    }
  }
}

//continueRead()==================================================================================
//continue to read the file : I could not get this function to work as intended.
boolean continueRead(){
  boolean readAgain = false;
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x3B);
  if(waitForResponse("continueRead")){       //wait for a response from the CH376S. If CH376S responds, it will be true. If it times out, it will be false.
     if(getResponseFromUSB()==0x14){         //CH376S will send 0x14 if this command was successful
       readAgain=true;
     }
  }
  return(readAgain);
} 

//fileCreate()========================================================================================
//the command sequence to create a file
boolean fileCreate(){
  boolean createdFile = false;
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x34);
  if(waitForResponse("creating file")){       //wait for a response from the CH376S. If file has been created successfully, it will return true.
     if(getResponseFromUSB()==0x14){          //CH376S will send 0x14 if this command was successful
       createdFile=true;
     }
  }
  return(createdFile);
}


//fileDelete()========================================================================================
//the command sequence to delete a file
void fileDelete(String fileName){
  setFileName(fileName);
  delay(20);
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x35);
  if(waitForResponse("deleting file")){       //wait for a response from the CH376S. If file has been created successfully, it will return true.
     if(getResponseFromUSB()==0x14){          //CH376S will send 0x14 if this command was successful
       Serial.println("Successfully deleted file");
     }
  }
}
  

//filePointer========================================================================================
//is used to set the file pointer position. true for beginning of file, false for the end of the file.
void filePointer(boolean fileBeginning){
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x39);
  if(fileBeginning){
    USB.write((byte)0x00);             //beginning of file
    USB.write((byte)0x00);
    USB.write((byte)0x00);
    USB.write((byte)0x00);
  } else {
    USB.write((byte)0xFF);             //end of file
    USB.write((byte)0xFF);
    USB.write((byte)0xFF);
    USB.write((byte)0xFF);
  }
  if(waitForResponse("setting file pointer")){       //wait for a response from the CH376S. 
     if(getResponseFromUSB()==0x14){                 //CH376S will send 0x14 if this command was successful
       Serial.println("Pointer successfully applied");
     }
  }
}


//fileClose=======================================================================================
//closes the file
void fileClose(byte closeCmd){
  Serial.println("Closing file:");
  USB.write(0x57);
  USB.write(0xAB);
  USB.write(0x36);
  USB.write((byte)closeCmd);                                // closeCmd = 0x00 = close without updating file Size, 0x01 = close and update file Size

  if(waitForResponse("closing file")){                      // wait for a response from the CH376S. 
     byte resp = getResponseFromUSB();
     if(resp==0x14){                                        // CH376S will send 0x14 if this command was successful
       Serial.println(">File closed successfully.");
     } else {
       Serial.print(">Failed to close file. Error code:");
       Serial.println(resp, HEX);
     }  
  }
}

//waitForResponse===================================================================================
//is used to wait for a response from USB. Returns true when bytes become available, false if it times out.
boolean waitForResponse(String errorMsg){
  boolean bytesAvailable = true;
  int counter=0;
  while(!USB.available()){     //wait for CH376S to verify command
    delay(1);
    counter++;
    if(counter>timeOut){
      Serial.print("TimeOut waiting for response: Error while: ");
      Serial.println(errorMsg);
      bytesAvailable = false;
      break;
    }
  }
  delay(1);
  return(bytesAvailable);
}

//getResponseFromUSB================================================================================
//is used to get any error codes or messages from the CH376S module (in response to certain commands)
byte getResponseFromUSB(){
  byte response = byte(0x00);
  if (USB.available()){
    response = USB.read();
  }
  return(response);
}



//blinkLED==========================================================================================
//Turn an LED on for 1 second
void blinkLED(){
  digitalWrite(LED, HIGH);
  delay(1000);
  digitalWrite(LED,LOW);
}

If you copy and paste this code directly into the Arduino IDE; you may get a warning like this when you compile the code:

"Low memory available, stability problems may occur".

I managed to run the sketch without any issues, however, I did experience problems with some of the methods when I had made further memory hungry modifications. If you do encounter problems, I would recommend that you eliminate any methods which you do not plan to use, and perhaps reduce the number of Serial.print statements throughout the code. However, please note that some of the methods will not work unless the module is in the correct state, so be careful which methods you delete. For example, I found that I could get some simple functionality without the "USBdiskMount()" method. However, I could not read/write data beyond a certain length without this method.

Also please note, that some of the methods called within the reading and writing sequence do not need to be called every time. They can be called once in setup, while other methods within the sequence will need to be called every time. I grouped them all together for simplicity.

Serial Commands

Have a look at the following presentation for a summary of the Serial commands used in this tutorial:

If you like this page, please do me a favour and show your appreciation :

Visit my ArduinoBasics Google + page.
Follow me on Twitter by looking for ScottC @ArduinoBasics.
I can also be found on Pinterest and Instagram.
Have a look at my videos on my YouTube channel.

However, if you do not have a google profile...
Feel free to share this page with your friends in any way you see fit.

108 comments:

cris9 July 2015 at 23:41
Sir is it possible to copy a file from 1 flash drive to another using two ch376s and arduino atmega 2560? Thanks. I hope for your response
ReplyDelete
Replies
cris mangio10 July 2015 at 02:10
Because i wish to make a portable file transfer device for a project using two of ths chips.
Thanks anyway! :)
ReplyDelete
Replies
Luca Innocenti21 August 2015 at 17:11
Nice Job. Thank you
I have a question.
It's possible to write a file to usb key without user interaction.... for example.
Starting without an usb inside the module, i put in the usb disk and automatically the code inside arduino intercept the event and write the file.
Thanks

Luca

ReplyDelete
Replies
Anonymous31 August 2015 at 05:18
Hi
i want to use a barcode scanner to get the barcode number and use that number to open an image with the same name. is this doable?

if so how?
ReplyDelete
Replies
Anonymous12 November 2015 at 03:16
I have been looking at this project with interest. I would like to create a portable backup device for a digital camera. Connect the camera to one of the USB boards and a large USB pen in the second USB board.
Anybody done anything like this and would like to share experiences.
ReplyDelete
Replies
vindude15 November 2015 at 16:00
Hello sir :) great tutorial...Is it possible to view directories inside the flash drive?Can you give me some suggestion if there is any chip that can accomplish this task as well???
ReplyDelete
Replies
Anonymous11 January 2016 at 11:34
Can I power this with 3.3 volts? do you know if i could hook this up to an ESP8266 to make it like a WiFi USB drive?
thanks
ReplyDelete
Replies
Anonymous13 January 2016 at 05:26
Greatjog Scott. I have a problem with the CH376EVT board. The board with USB and SD.
Your test program works fine on my Arduino Mega. The problem is that my PC cannot see the TEST4.TXT file create on the Arduino and the Arduino cannot see the files TEST2.TXT and TEST3.TXT created on the PC.
The USB drive is a Patriot 32GB drive freshly formatted with FAT32 and 16kB clusters.

Any suggestions?
Thank you
Jon W
ReplyDelete
Replies
Anonymous26 January 2016 at 01:25
Hi Sir Scott,

I'm a student...I want to create a 'device' that can read the contents of a flash drive and it has a screen to display the files and also can navigate through the existing files....

this device will be connected to a printer and will send a command to a printer to print....

so can I use CH376S for my project? will you give me some help?
it would really be a great help...

-Glen
ReplyDelete
Replies
Anonymous1 February 2016 at 13:58
Hi. I just followed all these instructions, but when I send 1 using serial monitor I get "TimeOut waiting for response: Error while: checking connection". I triple checked wiring. I suspect that my CH376S board is defective. Any suggestions?
ReplyDelete
Replies
Mahmoud Bagherian5 February 2016 at 02:26
hi sir,
i have a problem in writing process,
when i write my data in file, i get this message in serial terminal:

The CH376S module has been reset!
set_USB_Mode command acknowledged
USB is present
Checking USB disk connection status:
>Connection to USB OK
Mounting USB disk>USB Mounted - OK
Setting filename to:test4.txt
Writing to file:
may name is alex
Data Length:16
Write code (normally FF and 14): 10,14
Closing file:>File closed successfully.

why i get 0x10insted of 0xFF,
please help me,
sorry for my englsih
ReplyDelete
Replies
rashn23 March 2016 at 04:05
I found an interesting thing. Command returns not 0xFF, it returns the number of bytes written. And what is important: When you record a lot of data, if the next line exceeds the block size of 512 bytes (512 in my case), it is written only that part that fit into the 512 bytes, the rest is cut off.

To avoid this, I changed a little bit recording function. I publish an example of its use:

..........
String senda = "2016,3,22,18,33,NAN,NAN,NAN,NAN,38.0,22.0,0\n";
byte ttl = senda.length();

for (int i=0; i<120; i++)
{
byte sv = fileWriteAppendix(senda); //Write data to the end of the file
if (svwrite(0x57);
USB->write(0xAB);
USB->write(0x3C);
USB->write((byte) dataLength);
USB->write((byte) 0x00);
if(waitForResponse("setting data Length")){ // Wait for an acknowledgement from the CH376S module before trying to send data to it
if(getResponseFromUSB()==0x1E){ // 0x1E indicates that the USB device is in write mode.
USB->write(0x57);
USB->write(0xAB);
USB->write(0x2D);
USB->print(data); // write the data to the file
if(waitForResponse("writing data to file")){ // wait for an acknowledgement from the CH376S module
}
dataLength = USB->read();
USB->write(0x57);
USB->write(0xAB);
USB->write(0x3D); // This is used to update the file size. Not sure if this is necessary for successful writing.
if(waitForResponse("updating file size")){ // wait for an acknowledgement from the CH376S module
}
USB->read();
delay(100);
}
}

return dataLength;
}
ReplyDelete
Roja26 April 2016 at 06:58
I have gotten my code to work as desired and writing to the USB with the Arduino (Mega) still attached to the computer and sending Serial.print statements to the Serial monitor. I have tried to get it to run stand alone by commenting out all of the Serial.print lines. Then it seems to have problems writing and/or skipping write to usb lines. Is there a proper way to modify code so the Arduino can write to the USB unplugged from the computer?
Thanks Roja
ReplyDelete
Replies
Roja28 April 2016 at 01:01
I was able to set up the USB module on the MEGA Serial2. No improvement to my problem. I did realize that a successful USB write seems to depend on the IDE serial window being open at the time of the write, not just that the programming cable is plugged in to the computer and the IDE open. What does that mean? Thanks,
Roger
ReplyDelete
Replies
Unknown5 June 2016 at 23:29
would it be possible to read certain data in usb flash disk and use it to trigger the output? and when that data not detected(usb unplug) it will trigger the output to be off with delay.
ReplyDelete
Mehmet KALA3 July 2016 at 14:47
hi, i can txt file but this txt file doesn't view on computer. Used space of usb drive increases but i can't see this txt file. why?
ReplyDelete
Replies
Miguel Rodmen27 July 2016 at 01:50
Hi scott, do you have the fritzing sketch?
ReplyDelete
Replies
morosh30 July 2016 at 22:36
Hello and thank you for your wonderful job!!
I tried the above sketch, I have problem with writing, I got:

COMMAND4: Create and Write to File : TEST4.TXT
----------------------
The CH376S module has been reset !
set_USB_Mode command acknowledged
USB is present
Checking USB disk connection status
>Connection to USB OK
Mounting USB disk
>USB Mounted - OK
Setting filename to:
File could not be created, or it already exists
Closing file:
>File closed successful

there is no file'name after "Setting filename to:", after investigating for a while, I noticed that if wrData is short (just 5 characters) it works, otherwise no.
what's wrong? (using W7-x64, arduino 1.6.9)
thanks
ReplyDelete
Replies
Лаборатория-33 Лаборатория-3316 September 2016 at 19:44
Hello! Maybe you have some sample code for CH375B?
ReplyDelete
Replies
Anonymous19 October 2016 at 17:46
File Size Definition procedure is incorrect.
Please, replace everywhere

int fs = getFileSize(); //Get the size of the file

to

unsigned long int fs = getFileSize(); //Get the size of the file

and

unsigned long int getFileSize(){
unsigned long int fileSize=0;
Serial.println("Getting File Size");
USB.write(0x57);
USB.write(0xAB);
USB.write(0x0C);
USB.write(0x68);
delay(100);
Serial.print("FileSize =");
if(USB.available()){
fileSize = fileSize + USB.read();
}
if(USB.available()){
fileSize = fileSize + (USB.read()*256);
}
if(USB.available()){
fileSize = fileSize + (USB.read()*256*256);
}
if(USB.available()){
fileSize = fileSize + (USB.read()*256*256*256);
}
Serial.println(fileSize);
delay(10);
return(fileSize);
}
ReplyDelete
Replies
Anonymous20 October 2016 at 18:01
Not only change all ints to unsigned longs, but change
...
(USB.read()*256*256*256);
...
instead
...
(USB.read()*255*255*255);
...
Thanks

ReplyDelete
Replies
이재철21 October 2016 at 08:50
Hello, I use ch376s module to save data into USB memory stick but using this, I have some difficulties

1st, now I save data in main root of USB memory but I'm trying to make a folder in main root and make files in that folder. So, I wonder how I can make folder and create file to save data.

2nd, now I make a file using writeFile function and through appendFile function, write data sequentially. Size of one data is 21 byte and I save data in alternate lines.
But when arduino send 100 of data, only 80 of data are saved in USB memory. So, I wonder what reason of this data loss

Thank you .
ReplyDelete
Replies
Ravindra kumara12 November 2016 at 15:22
Sir I have problem about why after power connecting ch375 module & i am insert usb pen drive but not turn on ch375 module led how to power on module???
ReplyDelete
Replies
Anonymous17 November 2016 at 14:53
Hello Scott,

I've found about your page while trying to solve issues with my CH376 module.

I can create, write, edit directory info (file date) without error but when looking at the result on a computer, created files are visible but of size 0 byte and cannot be opened by windows ("file not found" error when clicking on the file). More over, the file date is 2004 which means the directory info edit wasn't too effective.

I've dumped the flash drive data (raw data of the flash memory) and I can see the file data is actually saved to the flash drive but failed to be connected to the directory data.

I've tried with three flash drives of different capacity, state and manufacturing date, same issue.

Is that something you experienced before? I would expect such IC to have much greater compatibility than this. So far it's 0% compatibility for me. I'm sort of thinking that module is glitchy/junk and I wonder if any alternatives available.

Thank you.
Daniel
ReplyDelete
Replies
Mohit Singh19 December 2016 at 18:59
It is reading, writing and appending TEST4.TXT on serial window but not creating text file on pendrive.
ReplyDelete
Replies
Unknown13 January 2017 at 14:58
Hello, have you tried writing (saving into the USB drive) for several times (> 10 times) and check if there's any data missing?

I've faced this problem that my data went missing (15 characters sent, left 10... returning error code 0x1E) if I save it for more than 10 times.

I tried to reduce the number of characters.. but still, the problem did not go away.
ReplyDelete
Replies
Friedrich Gauss22 January 2017 at 07:51
Works or Not works ?
I wan to use it
ReplyDelete
Replies
Alireza Molaee24 February 2017 at 02:37
Hi Scott,

I wanna use this code by Arduino mega2560
at the first step I receive this Error:

COMMAND1: CHECK CONNECTION
----------------------
TimeOut waiting for response: Error while: checking connection

Is there anything that I should changed when useing Mega 2560??

ReplyDelete
Replies
Durga Ganesh5 March 2017 at 22:52
hai sir,
i really use your artcle,
i have small clarification if i use any another micro controller is it work? except arduino
ReplyDelete
Replies
sander1 May 2017 at 01:02
hi scott,

I get problems if i read data longer than 40 bytes.
You wrote :
"//continue to read the file : I could not get this function to work as intended."

Does this mean it is not possible ?

ReplyDelete
Replies
Nestor Velasquez5 May 2017 at 10:53
Hi, Thanks much for this tutorial. Best resource I got so far regarding the possibility of file transfer from my data logger into a stick drive. Multiple resources regarding data logging in SD but all sketches I looked into so far are either real-time monitoring hooked in a computer, or practically prying out the SD Card from the data logger shield and then reading it via usb/SD adapter. My project would require placing the arduino and data logger et al hardware in a semi-permanent enclosure. It would store time/temperature data of a usual 3-4 hour cycle. From your point of view Scott, would it be possible to insert a SD stick in a USB port and the sketch inside the arduino automatically copy/transfer files from the SD card in the data logger. This would eliminate the need to open up the enclosure and pull out the arduino and pry out the SD card from the data logger, every 4-hour cycle or so. Would greatly appreciate your insight on this, and maybe guidance to get me to the right direction.
ReplyDelete
Replies
Pratik Gala30 May 2017 at 05:49
Hi, really a great job. I want to implement this. I want to send data available on serial monitor of master arduino to slave arduino using this. I dont want to write to any file just want to send data from master to slave. Is it possible to do so..?
ReplyDelete
Replies
Samah Himoud11 June 2017 at 05:59
Hi Scott, thank you for sharing!
I'm trying send use the same chip (ch376s) to tansfer data from atmegaxxx(I didnt choose which module yet) to usb memory stack and PC. so can I do this, and I need in the code in order to be able to trasfer data to PC via ch376s?
ReplyDelete
Replies
Samah Himoud13 June 2017 at 05:36
thank you for your help, I guess I only have the datasheet to answer my question!
ReplyDelete
Replies
black prince21 June 2017 at 01:33
Hi
Can we connect serial cable to this module like your fdti or cp2102 chip
ReplyDelete
Replies
Dave27 June 2017 at 07:36
Hello,

I am currently working on a few projects involving a SD card, and one with the CH375. I’ve had trouble getting my code to work so far. In the case of the CH375 I am talking to it via a parallel bus and believe the basic communication is working. I can send one of the commands which then triggers an interrupt, and then read the status and see the interrupt signal go in-active. Every time the status is 22 hex.

I’m wondering if part of my problem could be the FAT issue - all of the USB drives I’ve tried were formatted on my Windows 10 PC. I saw mention of the program you used to format a drive to one of the earlier FAT standards. Can you tell me what the exact program name is ? At the link you gave, there is mention of two programs ... so, I just want to make sure I am getting the one you said worked for you.

I did a little search and found this link which explains how to do the format at the DOS command prompt using the MS DISKPART command. I tried it with my SD card project - but still haven’t achieved success. Haven’t had time to use if on my USB drives and my CH375 project.

Here is the link:

http://www.instructables.com/id/Format-USB-Flash-Drive-to-FATFAT16-not-FAT32/

Thanks !
ReplyDelete
Replies
touseef27 June 2017 at 14:20
Hi Scott

can you please give a short tutorial to interface serial cable(cp2012 or ftdi) with ch376s module. please do the needful

greatly appreciate your support.

ReplyDelete
Replies
MOMO5 July 2017 at 18:14
Hello,
Actually im working on Arduino Uno microcontroller and i'm trying to control a vidéo USB Module.

To do that i am using an USB module CH376s which will be the bridge between the Arduino and the Video Module.

Actually the video module is considered like an USB key when i plugeed it to the computer i cant put any folder inside and when i put a video folder and eject (unmount) the module the video is played.

so i'm trying to do that using the arduino but i get a problem, when i try to create a file on the video module i lose the mount.

and what is bizzar to me is that when i stop in the mount step and i don't do anything else the module still mounted but when i send any command via the USB module (CH376) i lose the mount.

when i do the same steps for a normal USB key i don't get any problem.

That's it i'm bloqued and i can't figure out the problem i hope that you get a little idea about my problem and i hope you could help me.
PS : regarding the ch376 datasheet it suport UFI command but i don't know how i could send UFI command through the CH376;
ReplyDelete
Replies

Add comment

Feel free to leave a comment about this tutorial below.
Any questions about your particular project should be asked in the ArduinoBasics forum.

Comments are moderated due to large amount of spam.

Arduino Basics

Pages

7 May 2015

CH376S USB Read/Write module

Parts Required:

Remove the Jumper

Fritzing Sketch

Arduino Sketch

Serial Commands

108 comments:

This Week's Most Popular Posts

Get Email Notifications of My Latest Posts

Pages

7 May 2015

CH376S USB Read/Write module

Parts Required:

Remove the Jumper

Fritzing Sketch

Arduino Sketch

Serial Commands

108 comments:

This Week's Most Popular Posts

Get Email Notifications of My Latest Posts

Subscribe To ArduinoBasics